Re: МАКРОСЫ
Поправил и доработал резист, сейчас сам им качаю. Вот результат:
[PHP]
////////////////////////////////Resist by Sindo
//каст стенки и лечение во время ходьбы (1/3) (c ассистом)
/////////////////////////////////
set $westbtn j// walk+west
set $eastbtn l// walk+east
set $southbtn k // walk+south
set $ffcastbtn f9// CastSpell+FireField/WFT/TargetSelf
set $healbtn F11 // лечение бинтами через ассист
set #healwait 2900// задержка на отхиливание с бинта
set #ffcastwait 2000// задержка на каст фаерфилда
set #2scr 4// номер потока со скриптом ходьбы по стенке
set #worky charposy
set timer
:f
if hits < 150
send $healbtn
end_if
set #h 150 - hits
wait #healwait
if (hits = 150) and (#h = 0) or (timer >= 100000)
stop_script #2scr
repeat 10 // начало выравнивания (выравнивается упираясь в западную стену дома, ходя паралельно южной)
send $westbtn
wait 200
end_repeat
repeat 4
send $eastbtn
wait 200
end_repeat // конец выравнивания
:recast
if charposy = #worky
set timer
send $ffcastbtn
wait #ffcastwait
if (lastmsg fiz)
goto recast
end_if
start_script #2scr
else
repeat 3
send $southbtn
end_repeat
goto recast
end_if
end_if
goto f [/PHP][PHP]///////////////////////////////////Resist by Sindo
//ходьба по стенке (2/3)
///////////////////////////////////
// межстрочная задержка 100
set $westbtn j // walk+west
set $eastbtn l // walk+east
repeat 4
send $westbtn
wait 50
end_repeat
:rep
repeat 7
send $eastbtn
end_repeat
repeat 7
send $westbtn
end_repeat
goto rep [/PHP][PHP]//////////////////////////////////Resist by Sindo
//отход если мало хп (3/3)
//////////////////////////////////
// межстрочная задержка 20
set #2scr 4 // номер потока со скриптом ходьбы по стенке
set $northbtn i // walk+north
set $southbtn k // walk+south
set #a 0
:start
if (hits < 60) and (hits >= 1)
pause_script #2scr
repeat 3
send $northbtn
wait 200
end_repeat
while hits < 120
wait 500
end_while
repeat 3
send $southbtn
wait 200
end_repeat
resume_script #2scr
end_if
if hits < 1
repeat 5
alarm
wait 2s
end_repeat
set #a #a + 1
if #a > 20
stop_script all
end_if
end_if
goto start [/PHP]Настройка и запуск:
1) вставить скрипты в 3 разных окна пилота
2) проверить бинды в верхних частях скриптов на соответствие действиям описанным в комментариях
3) загрузить в пак чару как можно больше бинтов и реги для каста фаер филда
4) поставить чара вплотную к южной стене базы на 4-й тейл от западной
5) проверить стоит ли чар за ам зоной дома, если нет то передвинуть южный забор на 1 тейл на юг и вновь выставить чара (п. 4)
6) запустить скрипты №1 №3
7) переодически проверять наличие у чара реагентов и бинтов, и не умер ли чар ( если умрет он будет громко кричать (в разработке))
Советы:
1) когда вы начнете юзать этот скрипт у вашего питомца должно быть не менее 60 магери и 80 хилинга, иначе будет много физлов и простоя на отхиливание
2) чтобы засунуть побольше итемов в пак чару убейте его, положите туда все что нужно и ресните. (? ибо могли пофиксить)
3) качаться надо в арморе который не дает плюсов к скилу резиста или без армора
4) качаться в полиморфе глюпо ибо в полиморфе нельзя хиляться
5) при хилинге 90 и гм магери на 1к бинтов приходится ~40 кастов фаерфилда.
Принцип работы скрипта:
1) чар выравнивается об западную стену дома бегая паралельно южной
2) кастует на себя фаерфилд
3) бегает вдоль южного забора по фаерфилду при этом хилясь и невыходя за пределы фаерфилда
4) если хп меньше 60 чар отходит в сторону и хилится, восстановив хп до 120 возвращается и продолжает бегать
5) если стенка почти погасла или у чара 150 хп все повторяется с 1-го пункта
6) при этом если чар умер он будет долго кричать ( аларм пилота), а потом заткнется и остановит все скрипты (в разработке)
7) медитация не требуется, т.к. для восстановления более чем достаточно пассивного регена.
__________________
May the Force be with you..
|